4.3. 터치센싱을 이용한 위빙 폭 자동 설정 아크센싱

하기와 같은 두 작업물에 모두 적용할 수 있는 하나의 작업 프로그램을 생성합니다.

그림 4.2 Butt 터치센싱, 아크센싱 작업물

작업 환경은 다음과 같이 가정합니다.

두 작업물 사이를 용접하는 공정.

180도 평면 위빙

용접 진행방향은 X+ 방향. 작업물 터치센싱은 Y방향으로 좌우 수행

아크센싱 파라미터 설정은 기존에 완료된 것으로 가정

4.0mm gap인 경우 용접 속도는7.0mm/sec

8.0mm gap인 경우 용접 속도는 3.5mm/sec

작업 순서는 다음과 같습니다.

1) 터치 센싱 명령어를 이용하여 종료점 Butt 부분의 용접 중심 위치, gap 거리를 측정

2) 터치 센싱 명령어를 이용하여 시작점 Butt 부분의 용접 중심 위치, gap 거리를 측정

3) V10! 값이 허용 값 이내인지 판단. 2.0mm ~ 10.0mm 범위를 벗어나는 경우 정지

4) 측정 된 거리의 절반을 각각 벽방향(좌측면), 타방향(우측면) 거리로 지정

5) 용접 속도는 4.0mm/sec, 8.0mm/sec 시 속도를 이용하여 보간 계산. Gap이 4.0mm보다 작으면 7.0mm/sec, 8mm를 초과하면 4.0mm/sec 고정 속도 적용

6) 계산된 값을 이용하여 위빙 폭, 용접진행속도를 자동 입력하여 작업 진행

7) 작업 진행이 완료된 후 원래 시작 위치로 복귀

그림 4.3 Butt 터치센싱과 아크센싱

l 예시 프로그램은 다음과 같습니다.

~~~~~~~아크센싱 프로그램: 0002.JOB~~~~~~~~~~~~~~~

'Butt 아크센싱 프로그램

'1자리: 시작조건, 10자리: 종료조건

S1 MOVE P,S=60%,A=3,T=1 ' 1: 동작 시작점

S2 MOVE L,S=30%,A=3,T=1 ' 2: 종료점 터치센싱 위치

TOUCHSEN TSC#=2,+TY,-TZ,5,P10,V11! ' 3: 종료점 터치센싱. P10에 위치 저장

S3 MOVE L,S=30%,A=3,T=1 ' 4: 시작점 터치센싱 위치

TOUCHSEN TSC#=3,+TY,-TZ,5,P1,V1! ' 5: 시작점 터치센싱. P1에 위치 저장

'Calc. weld speed, width according to Gap V1! 갭에 따른 속도 설정

IF V1!<2.0 OR V1!>10.0 THEN ' 허용 범위 초과

GOTO *Error

ELSEIF V1!<4.0 THEN ' 4mm 이하이면 7mm/sec로 고정

V3!=7.0 'Weld speed at start

ELSEIF V1!>8.0 THEN ' 8mm 이상이면 4mm/sec로 고정

V3!=4.0 'Weld speed at start

ELSE '4~8mm범위내인 경우 선형 보간으로 속도 계산

V3!=(7-3.5)/(4-8)*V1!+10.5 'Linear interpolated weld speed at start

ENDIF

V4!=V1!/2.0 'left side width 'Gap 의 절반을 좌측 위빙 폭으로 지정

V5!=V1!/2.0 'right side width 'Gap 의 절반을 우측 위빙 폭으로 지정

'--------------------------------------------------------

'Calc. weld speed, width according to Gap V11!

IF V11!<2.0 OR V11!>10.0 THEN ' 허용 범위 초과

GOTO *Error

ELSEIF V11!<4.0 THEN ' 4mm 이하이면 7mm/sec로 고정

V13!=7.0 'Weld speed at start

ELSEIF V11!>8.0 THEN ' 8mm 이상이면 4mm/sec로 고정

V13!=4.0 'Weld speed at start

ELSE '4~8mm범위내인 경우 선형 보간으로 속도 계산

V13!=(7-3.5)/(4-8)*V11!+10.5 ' Linear interpolated weld speed at end

ENDIF

V14!=V11!/2.0 'left side width

V15!=V11!/2.0 'right side width

'---------------------------------------------------------

S4 MOVE L,P11,S=20%,A=3,T=1 ' 6: 용접 시작 점으로 이동

WEAVON WEV#=2 ' 7: 위빙, 아크센싱 시작

ARCON ASF#=2 ' 8: 용접 시작

ARC_COND L,V3!,V4!,V5!,2,400,32 ' 9: Start of weld parameter continuous change

S5 MOVE L,P10,S=60cm/min,A=3,T=1 '10: 용접 종료 점으로 이동

ARC_COND L,V13!,V14!,V15!,2,400,32 '11: End of weld parameter continuous change

ARCOF ASF# '12: 용접 종료

WEAVOF '13:위빙, 아크센싱 종료

S6 MOVE P,S=60%,A=3,T=1 '14: 동작 종료점

END

*Error '15:갭의 범위 이탈 시 퇴피 위치

DO200=1 '16: 에러 표시를 위해 신호 출력

STOP '17:로봇 정지

END

~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

4.3. 터치센싱을 이용한 위빙 폭 자동 설정 아크센싱​

4.3. 터치센싱을 이용한 위빙 폭 자동 설정 아크센싱